Regen Volume (UT2003)

1. Introduction
2. Code source
3. Explication du code

Créé le 10/05/2003
Dernière mise à jour le 10/05/2003

1) Introduction

Il s'agit d'un volume que le mappeur peut ajouter dans sa map une fois le package du script ouvert. La particuliarité de ce volume est qu'il régénère les joueurs qui se trouvent a l'intérieur de celui-ci.
Le problème de ces actors si spéciaux que sont les volumes, c'est qu'ils ne gèrent pas les functions de temps (Timer(), Tick()) or on a besoin de Timer() pour régénéré les joueurs chaque seconde.
Il faut donc spawné un actor exprés (VolumeTimer) qui va s'en occupé, son Timer() lancera la function TimerPop() du volume.

Top

2) Code source

//===========================================
// RegenVolume
// created by Crokx
// 10/05/2003 (dd/mm/yyyy)
//===========================================
class RegenVolume extends PhysicsVolume;


var() int RegenAmount;
var() int RegenLimit;
var VolumeTimer RegenTimer;


//=============================
// Dés le début dans la partie
//=============================
simulated function PostBeginPlay()
{
    Super.PostBeginPlay();

    RegenAmount = Min(RegenAmount, RegenLimit);
    RegenTimer = Spawn(class'VolumeTimer', SELF);
    if(RegenTimer != None) RegenTimer.V = SELF; // inutile car en spawnant le volume Timer avec un Owner SELF (second paramètre) il s'assigne tout seul cette variable dans son propre code
}


//===============================
// Appelé par RegenTimer.Timer()
//===============================
function TimerPop(VolumeTimer VT)
{
    local Pawn P;

    if(VT != RegenTimer) return;

    ForEach TouchingActors(class'Pawn', P)
    {
        if((P != None)
        && (P.IsPlayerPawn())
        && (P.Health < RegenLimit))
            P.Health = Min(P.Health+RegenAmount, RegenLimit);
    }
}


//=========
// Default
//=========
defaultproperties
{
    RegenAmount=5
    RegenLimit=100
}

Top

3) Explication du code

Déclaration des variables:

• RegenAmount la quantité d'énergie régénéré a chaque fois...
• RegenLimit ...si cette limite d'énergie n'est pas atteinte
• RegenTimer l'actor qui va servir de Timer()

Dés le début dans la partie:

• Force RegenAmount a être au maximum égal a la RegenLimit
• On fait apparaîttre un actor de type VolumeTimer qui va servir de Timer() au volume tout en l'assignant directement a la variable RegenTimer
• Si RegenTimer existe bien
• On assigne le V du RegenTimer (qui est un PhysicsVolume) a ce volume

Note:
Pour mieux comprendre le VolumeTimer, ouvrez UnrealEd et éditez le, il se trouve dans Actor/Info/.

Le RegenTimer lance dans son Timer() le TimerPop() du volume:

• On déclare une variable de type Pawn en P
• Si cette function n'est appelé par le bon VolumeTimer (RegenTimer) alors le code ne va pas plus loin avec return
• Renvoi tous les Pawn dans ce volume par la variable P
• S'il y a bien un pawn & que c'est bien un joueur & que son niveau énergie est inférieur a RegenLimit
• Alors l'énergie de ce pawn = son énergie + RegenAmount ou,  au maximum son énergie égal RegenLimit (car la function Min() renvoi la valeur la plus petite des 2 nombres)

Top