Random Weapon (UT2003)

1. Introduction
2. Code source
3. Explication du code

Créé le 23/07/2003
Dernière mise à jour le 23/07/2003

1) Introduction

Random Weapon est un mutator pour Unreal Tournament 2003 qui donne une arme au hasard à chaque respawn.

Top

2) Code source

Mutator:

//===========================================
// Random Weapon
// created by Crokx
// 27/11/2003 (dd/mm/yyyy)
//===========================================
class RandomWeapon extends Mutator;


//==================
// A chaque respawn
//==================
function ModifyPlayer(Pawn Other)
{
    local int Random;

    Random = Rand(7);

    switch(Random)
    {
        case 0:
        Other.GiveWeapon("xWeapons.BioRifle");
        break;

        case 1:
        Other.GiveWeapon("xWeapons.ShockRifle");
        break;

        case 2:
        Other.GiveWeapon("xWeapons.LinkGun");
        break;

        case 3:
        Other.GiveWeapon("xWeapons.Minigun");
        break;

        case 4:
        Other.GiveWeapon("xWeapons.FlakCannon");
        break;

        case 5:
        Other.GiveWeapon("xWeapons.RocketLauncher");
        break;

        case 6:
        Other.GiveWeapon("xWeapons.SniperRifle");
        break;
    }

    if(NextMutator != None)
        NextMutator.ModifyPlayer(Other);
}


//=========
// Default
//=========
defaultproperties
{
    FriendlyName="Random Weapon"
    Description="Give a random weapon when a player respawn."
}

Second exemple du mutator:

//===========================================
// Random Weapon
// created by Crokx
// 27/11/2003 (dd/mm/yyyy)
//===========================================
class RandomWeapon extends Mutator;


//===========
// Variables
//===========
var string RandomWeaponName[7];


//==================
// A chaque respawn
//==================
function ModifyPlayer(Pawn Other)
{
    local int Random;

    Random = Rand(7);
    Other.GiveWeapon(RandomWeaponName[Random]);

    if(NextMutator != None)
        NextMutator.ModifyPlayer(Other);
}


//=========
// Default
//=========
defaultproperties
{
    RandomWeaponName(0)="xWeapons.BioRifle"
    RandomWeaponName(1)="xWeapons.ShockRifle"
    RandomWeaponName(2)="xWeapons.LinkGun"
    RandomWeaponName(3)="xWeapons.Minigun"
    RandomWeaponName(4)="xWeapons.FlakCannon"
    RandomWeaponName(5)="xWeapons.RocketLauncher"
    RandomWeaponName(6)="xWeapons.SniperRifle"

    FriendlyName="Random Weapon"
    Description="Give a random weapon when a player respawn."
}

Fichier INT:

[Public]
Object=(Class=Class, MetaClass=Engine.Mutator, Name=RandomWeapon.RandomWeapon)

Top

3) Explication du code

Mutator:

A chaque respawn:

• On met a variable Random = un nombre aléatoire de 0 a 6.
• On switche la variable Random et suivant sa valeur, on donne une arme au joueur avec sa function GiveWeapon().

Propriétés par défaults:

• Voir ce tutorial pour les explications des variables.

Second exemple du mutator:

Variables:

• On déclare une chaîne de 7 variables de type string (texte)

A chaque respawn:

• On met a variable Random = un nombre aléatoire de 0 a 6.
  On donne une arme au joueur, mais en appelant sa function GiveWeapon() avec un paramètre aléatoire.

Propriétés par défaults:

• On assigne la chaîne de variables RandomWeaponName.
• Voir ce tutorial pour les explications des variables.

Top