Head Shot Bonus (UT2003)

1. Introduction
2. Code source
3. Explication du code

Créé le 01/06/2003
Dernière mise à jour le 01/07/2003

1) Introduction

Head Shot Bonus est un mutator pour Unreal Tournament 2003 qui donnera 1frag supplémentaire a celui qui tire a la tête de son adversaire avec son lightning gun. (+2frags)
En Team Deathmatch, l'équipe gagne aussi 1frag supplémentaire, mais pas en Capture The Flag ou Bombing Run.
On a besoin d'un GameRules pour accéder a la function PreventDeath et la modifié.
Le mutator sert juste pour faire apparaîttre dans le jeu le HeadShotBonusGameRules et a l'ajouter a la chaîne des GameRules du GameType comme pour le mutator d'origine Vampire par exemple. (sans cette chaîne le GameType prendrais en charge un seul GameRules et donc un seul mutator de ce type)

Top

2) Code source

Mutator:

//===========================================
// Head Shot Bonus
// created by Crokx
// 01/07/2003 (dd/mm/yyyy)
//===========================================
class HeadShotBonus extends Mutator;


//=============================
// Dés le début dans la partie
//=============================
function PostBeginPlay()
{
    local GameRules GR;

    Super.PostBeginPlay();

    GR = spawn(class'HeadShotBonusGameRules');
    if(Level.Game.GameRulesModifiers == None)
        Level.Game.GameRulesModifiers = GR;
    else Level.Game.GameRulesModifiers.AddGameRules(GR);
    Destroy();
}


//=========
// Default
//=========
defaultproperties
{
    FriendlyName="Head Shot Bonus"
    Description="2frags for one head shot."
}

GameRules:

class HeadShotBonusGameRules extends GameRules;


var private bool bTeamFrag;


//=============================
// Dés le début dans la partie
//=============================
function PostBeginPlay()
{
    bTeamFrag = ((Level.Game.IsA('TeamGame')) && (TeamGame(Level.Game).bScoreTeamKills));
}


//================================
// Quand un joueur viens de tombé
//================================
function bool PreventDeath(Pawn Killed, Controller Killer, class<DamageType> damageType, vector HitLocation)
{
    if((damageType == class'DamTypeSniperHeadShot')
    && (Killer != None)
    && (Killer.PlayerReplicationInfo != None))
    {
        if(Killer.Pawn != None)
            Killer.Pawn.ClientMessage("HeadShot +2frags");
        Killer.PlayerReplicationInfo.Score += 1;
        if((bTeamFrag)
        && (Killer.PlayerReplicationInfo.Team != None))
            TeamGame(Level.Game).Teams[Killer.PlayerReplicationInfo.Team.TeamIndex].Score += 1;
    }

    return Super.PreventDeath(Killed, Killer, damageType, HitLocation);
}

Fichier INT:

[Public]
Object=(Class=Class, MetaClass=Engine.Mutator, Name=HeadShotBonus.HeadShotBonus)

Top

3) Explication du code

Mutator:

Dés le début dans la partie:

• On ajoute nôtre GameRules, voir ce tutorial pour les explications.

Propriétés par défaults:

• Voir ce tutorial pour les explications des variables.

GameRules:

Déclaration des variables:

• Déclare une variable bool bTeamFrag privé, que seul ce code peut y accéder

Dés le début dans la partie:

• Assigne bTeamFrag suivant Si le GameType est bien un TeamGame & Si les frags compte aussi pour l'équipe (on connais ca avec la variable bScoreTeamKills du TeamGame)

Quand un joueur viens de tombé:

• SI le type de dégat est bien un tir a la tête avec un lightning gun
  ET SI il y a bien un fragger
  ET SI ce fragger a bien un PRI (PlayerReplicationInfo)
• SI le fragger a un pawn
• On utilise son pawn pour executé un petit message
• Ajoute 1point au compteur de frag du fragger
• SI les frags d'équipe son compté
  ET SI le fragger et bien dans une équipe (si son PRI a un Team)
• Ajoute 1point a l'équipe du fragger via la variable du GameType, Teams[x].Score.
• On renvoie les paramètres de cette function de la classe supérieure.

Top