Dark Low Health (UT2003)

1. Introduction
2. Code source
3. Explication du code

Créé le 23/07/2003
Dernière mise à jour le 23/07/2003

1) Introduction

Dark Low Health est un mutator pour Unreal Tournament 2003 qui fait en sorte que moins un joueur a d'énergie et plus il voit noir.
Mutator trés basique, comme le mutator d'origine Regen (Guérison en Français) tous se passe dans le Timer() en boucle.

Top

2) Code source

Mutator:

//===========================================
// Dark Low Health
// created by Crokx
// 23/07/2003 (dd/mm/yyyy)
//===========================================
class DarkLowHealth extends Mutator;


//=============================
// Dés le début dans la partie
//=============================
function PostBeginPlay()
{
    SetTimer(1.5, TRUE);
}


//==================================================
// Moins le joueur a d'énergie et plus il voit noir
//==================================================
function Timer()
{
    local Controller C;

    for(C=Level.ControllerList; C!=None; C=C.NextController)
    {
        if((C.IsA('PlayerController'))
        && (C.Pawn != None)
        && (C.Pawn.Health < 75))
        {
            if(C.Pawn.Health < 25) PlayerController(C).ClientFlash(0.2, vect(16,16,16));
            else if(C.Pawn.Health < 50) PlayerController(C).ClientFlash(0.4, vect(32,32,32));
            else PlayerController(C).ClientFlash(0.6, vect(64,64,64));
        }
    }
}


//=========
// Default
//=========
defaultproperties
{
    FriendlyName="Dark Low Health"
    Description="Dark Low Health by Crokx."
}

Fichier INT:

[Public]
Object=(Class=Class, MetaClass=Engine.Mutator, Name=DarkLowHealth.DarkLowHealth)

Top

3) Explication du code

Mutator:

Dés le début dans la partie:

• On lance Timer() en boucle avec une intervalle 1,5 seconde

Moins le joueur a d'énergie et plus il voit noir:

• C variable de type Controller
• Boucle for qui renvoie tous les joueurs présent dans la map par C
• SI c'est un controller de type PlayerController (joueur Humain et non Bot)
  ET SI ce controller a un Pawn
  ET SI son niveau d'énergie (accéder via son Pawn) est inférieur a 75
• SINON énergie est inférieur a 25 il a un gros flash noir
• SINON SI son énergie est inféreur a 50 (et donc plus de 25) il a un flash noir moyen
• SINON (avec moins de 75 d'énergie et donc plus de 50) un petit flash noir

Propriétés par défaults:

• Voir ce tutorial pour les explications des variables.

Top