Deploy Regen Point (U2XMP)

1. Introduction
2. Code source
3. Explication du code

Créé le 17/12/2003
Dernière mise à jour le 17/12/2003

1) Introduction

Deploy Regen Point est un mutator pour l'extention XMP d'Unreal 2, qui régénérera tous les membres d'une équipe à proximité d'un point de déploiment que cette équipe contrôle.

Top

2) Code source

Mutator:

//============================================
// Deploy Regen Point v1.00
//
// created by Crokx @ 17/12/2003 (dd/mm/yyyy)
//============================================
class DeployRegenPoint extends Mutator config(RegenPoint);


//===========
// variables
//===========
var() config int RegenAmount;
var() config int RegenRate;
var private array<DeploymentPoint> DeployPointList;


//===============
// Mutator Begin
//===============
function PostBeginPlay()
{
    PreCacheDeployPointList();

    Super.PostBeginPlay();

    SetTimer(RegenRate, TRUE);
}


//===============
// Mutator loop
//===============
function Timer()
{
    local int i;
    local U2Pawn P;

    for(i=0; i<DeployPointList.Length; i++)
    {
        if(DeployPointList[i].Team != 255) // ignore neutral point
        {
            foreach DeployPointList[i].CollidingActors(class'U2Pawn', P, 224) // Radius = 224 * DeployPointList[i].DrawScale
            {
                if((P != None)
                && (P.Health > 0)
                && (P.PlayerReplicationInfo != None)
                && (P.PlayerReplicationInfo.Team != None)
                && (P.PlayerReplicationInfo.Team.TeamIndex == DeployPointList[i].Team)
                && (P.Health < P.default.Health))
                {
                    P.Health = FMin(P.Health+RegenAmount, P.default.Health);
                    P.PlaySound(Sound'U2A.PowerUps.HealthPowerUp', SLOT_Misc, 2);
                }
            }
        }
    }
}


//===========================
// PreCache DeployPointList
//===========================
function PreCacheDeployPointList()
{
    local DeploymentPoint NextDP;

    foreach AllActors(class'DeploymentPoint', NextDP)
    {
        if(NextDP != None)
        {
            DeployPointList.Length = DeployPointList.Length+1;
            DeployPointList[DeployPointList.Length-1] = NextDP;
        }
    }

    log("DeployRegenPoint mutator: "$DeployPointList.Length$" DeploymentPoint found in "$Level.Title);
}


//=====================
// Default Properties
//=====================
defaultproperties
{
    RegenAmount=5
    RegenRate=2
}

Fichier INT:

[Public]
(Object=(Class=Class, MetaClass=Engine.Mutator, Name=DeployRegenPoint.DeployRegenPoint, Description="The DeployPoint regenerate his owned team members nearness of this point.")

Fichier INI:

[DeployRegenPoint.DeployRegenPoint]
RegenAmount=5
RegenRate=2

Top

3) Explication du code

Mutator:

Début du mutator:

• On lance PreCacheDepoyPointList() qui enregistre dans la chaîne de variables DeployPointList tous les points de déploiments de la carte, ce qui évitera par la suite d'utiliser la trés lente function AllActors() à chaque fois
• On lance Timer() en boucle avec une intervalle x seconde (x = RegenRate dans DeployRegenPoint.ini)

Boucle du mutator:

• i variable de type int, utilisé pour accéder aux maillons de la chaîne DeployPointList
• P variable de type U2Pawn, utilisé pour renvoyé tous les joueur à pied trouvé
• Pour tous les points de déploiments de la chaîne DeployPointList
• Qui ne sont pas neutre
• On renvoie a partir de ce point jusqu'a une distance maximale de 224 unités, tous les acteurs de type U2Pawn par P avec la function CollidingActor() (voir ce tutorial pour plus d'info sur ce dernier)
• S'il y a bien un joueur trouvé
  & SI ce joueur est en vie
  & SI ce joueur a un PRI
  & SI ce joueur est dans une équipe
  & SI son équipe contrôle ce point de déploiment
  & SI ce joueur a besoin d'énergie
• On lui donne x d'énergie (x = RegenAmount dans DeployRegenPoint.ini), avec FMin on lui donne au maximum son énergie par défault, car sans ça par exemple s'il a 98, il aurrait 103 aprés.
• Un son est exécuté a partir de ce joueur pour lui indiqué sa régénération

Mise en mémoire cache des points de déploiments:

• NextDP variable de type DeploymentPoint
• On renvoie via la function AllActors() tous les acteurs trouvé dans la map de type DeploymentPoint par NextDP
• Si on trouve un DeploymentPoint
• On augmente la chaîne de variables d'une unité
• Le dernier maillon de la chaîne = NextDP, le points de dépoiment trouvé
  (toutes les chaînes de variables commence par 0 donc on met: la longueur de la chaîne moins 1 pour avoir le dernier maillon, voir ce tutorial pour plus d'info)
• On met un petit message dans de log pour indiquer le nombre de points de déploiments trouvé dans la map

Propriétés par défaults:

• On met les valeurs des variables configurables par défault au cas ou DeployRegenPoint.ini n'existe pas.

Top